网站建设 郑州网站建设 网站制作 网页设计 网站设计 郑州建网站 - 爱易在线

网站地图 | 网站Tags标签 | RSS订阅 | 加入收藏
您的位置:网站首页 > 博客笔记 > 技术交流 > 正文 技术交流相关信息

Asp vbscript 通过CDO.Message发送邮件

作者:郑州网站建设 2020/8/29 0:54:18 点击: 来源:

Asp发送邮件大多用的都是jmail,但是jmail收费,很多服务器不支持此组件。

其实通过windows服务器自带的CDO.Message即可发送邮件,无需额外安装组件。

下面是CDO.Message发送邮件的函数封装。


'=======================================================
'参数说明
'MailAddress : 发件服务器的地址,如smtp.163.com
'LoginName     ----登录用户名(不需要请填写"")
'LoginPass     ----用户密码(不需要请填写"")
'Subject     : 邮件标题
'EmailTo     : 收件人邮件地址
'Sender      : 发件人姓名
'Content     : 邮件内容
'****************************************************
Function SendMailByCDO(MailAddress, LoginName, LoginPass, Subject, EmailTo, Sender, Content)
    Const cdoSendUsingMethod="http://schemas.microsoft.com/cdo/configuration/sendusing"
    Const cdoSendUsingPort=2
    Const cdoSMTPServer="http://schemas.microsoft.com/cdo/configuration/smtpserver"
    Const cdoSMTPServerPort="http://schemas.microsoft.com/cdo/configuration/smtpserverport"
    Const cdoSMTPConnectionTimeout="http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
    Const cdoSMTPAuthenticate="http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
    Const cdoBasic=1
    Const cdoSendUserName="http://schemas.microsoft.com/cdo/configuration/sendusername"
    Const cdoSendPassword="http://schemas.microsoft.com/cdo/configuration/sendpassword"
    
    Dim objConfig
    Dim objMessage
    Dim Fields
    Set objConfig = Server.CreateObject("CDO.Configuration")
    Set Fields = objConfig.Fields
    
    With Fields
        .Item(cdoSendUsingMethod) = cdoSendUsingPort
        .Item(cdoSMTPServer) = MailAddress
        .Item(cdoSMTPServerPort) = 25
        .Item(cdoSMTPConnectionTimeout) = 10
        .Item(cdoSMTPAuthenticate) = cdoBasic
        .Item(cdoSendUserName) = LoginName
        .Item(cdoSendPassword) = LoginPass
    .Update
    End With
    
    Set objMessage = Server.CreateObject("CDO.Message")
    Set objMessage.Configuration = objConfig
    With objMessage
        .BodyPart.Charset = "utf-8"
        .To=EmailTo
        .From=LoginName
        .Subject=Subject
        .HtmlBody=Content
        .Send
    End With
    
    Set Fields = Nothing
    Set objMessage = Nothing
    Set objConfig = Nothing
    
    If Err Then
        SendMailByCDO = Err.Description
        Err.Clear
    Else
        SendMailByCDO = "OK"
    End If
End Function


Tag:
分享到:

上一篇:html meta头优化

下一篇:没有资料

技术交流推荐阅读

用户评论

最新博文

热门排行

推荐信息

关于爱之易| 付款方式| 联系我们| 网站地图| 网站Tags标签 | RSS订阅